TEXTJOIN

TEXTJOIN(delimiter, ignore_empty, text1 [,text2] [..])

Returns the text string that is a concatenation of several strings with a delimiter.

delimiter	One or more delimiter characters.
ignore_empty	A logical value indicating if empty cells are ignored: True or 1 = Yes False or 0 = No
text1	The first text item.
text2	(Optional) The second text item.

REMARKS

* This function was added in Excel 2019.
* You can have a maximum of 252 text arguments.
* If the resulting string has more than 32,767 characters, then #VALUE! is returned.
* If the "delimiter" is not provided, then an empty string is used.
* If the "delimiter" is not recognised as text, then #NAME? is returned.
* If the function is not available, then #NAME? is returned.
* You can use the CONCAT function to return a concatenation of strings (without any delimiters).
* You can use the TEXT function to return a number as a formatted text string.
* You can use the TEXTAFTER function to return the characters from the end of a text string after a delimiter.
* You can use the TEXTBEFORE function to return the characters from the start of a text string before a delimiter.
* You can use the TEXTSPLIT function to return a text string split into multiple columns using delimiters.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B	C
1	=TEXTJOIN("", FALSE, "the start", " and the end") = the start and the end	mon	one
2	=TEXTJOIN(" ", FALSE, "the start", "and the end") = the start and the end	tue
3	=TEXTJOIN(, FALSE, "ab", "cd", "ef", "gh") = abcdefgh		two
4	=TEXTJOIN(",", FALSE, "ab", "cd", "ef", "gh") = ab,cd,ef,gh	wed
5	=TEXTJOIN("--", FALSE, 1, 2, 3, 4) = 1--2--3--4	thu	three
6	=TEXTJOIN(",", FALSE, B1:B5) = mon,tue,,wed,thu
7	=TEXTJOIN(", ", TRUE, B1:C5) = mon, one, tue, two, wed, thu, three
8	=TEXTJOIN(" - ", TRUE, B1:B5, C1:C5) = mon - tue - wed - thu - one - two - three
9	=TEXTJOIN(invalid_named_range, TRUE, "Mon", "Tue") = #NAME?
10	=TEXTJOIN(“ “, TRUE, "Mon", "Tue") = #NAME?

1 - What is the combined string when you concatenate "the start" and " and the end" with no delimiter character.
2 - What is the combined string when you concatenate "the start" and "and the end" with the delimiter character " " (space).
3 - What is the combined string when you concatenate "ab", "cd", "ef" and "gh" with no delimiter character. The delimiter has not been provided.
4 - What is the combined string when you concatenate "ab", "cd", "ef" and "gh" with the delimiter character "," (comma).
5 - What is the combined string when you concatenate the numbers 1, 2, 3 and 4 with the delimiter character "--".
6 - What is the combined string when you concatenate the values in cells "B1:B5" with the delimiter ",". The empty cells are not being ignored.
7 - What is the combined string when you concatenate the values in cells "B1:C5" with the delimiter ", ". The empty cells are being ignored.
8 - What is the combined string when you concatenate the values in cells "B1:B5" and "C1:C5" with the delimiter " - ". The empty cells are being ignored.
9 - What is the combined string when the delimiter is referring to an invalid named range.
10 - What is the combined string when the delimiter is not recognised as text. These speech marks are not correct.