VSTACK

VSTACK(array1 [,array2] [..])

Returns the array after putting multiple arrays on top of each other.

array1	The first array to be appended.
array2	(Optional) The second array to be appended.

REMARKS

* This function was added in Microsoft 365.
* This function can create a Dynamic Array Formula.
* This function can be used to combine data from multiple worksheets.
* If the arrays are single rows, they are stacked on top of each other. Example 1.
* If the arrays are single columns, they are stacked in a single column. Example 2.
* If the arrays are not the same size, they are padded with #N/A.
* You can have a maximum of 254 arguments.
* You can use the HSTACK function to return the array after putting multiple arrays next to each other.
* You can use the TOCOL function to return the array transformed into a single column.
* You can use the TOROW function to return the array transformed into a single row.
* This function was first released in March 2022.
* For the Microsoft documentation refer to support.microsoft.com

	A	B	C	D	E	F
1	=VSTACK(C1:D1,C2:D2) = {1,2 ; 5,6}		1	2	3	4
2	=VSTACK(C1:C2,D1:D2) = {1 ; 5 ; 2 ; 6}		5	6	7
3	=VSTACK(C1:D1,C3:D3) = {1,2 ; 8,9}		8	9	10
4	=VSTACK(C1:D1,C2:D2,C3:D3) = {1,2 ; 5,6 ; 8,9}		11
5	=VSTACK(C1:D1,C2:D3) = {1,2 ; 5,6 ; 8,9}
6	=VSTACK(C1:C3,D1:D3) = {1 ; 5 ; 8 ; 2 ; 6 ; 9}
7	=VSTACK(C1:C4,D1:D4) = {1 ; 5 ; 8 ; 11 ; 2 ; 6 ; 9 ; 0}
8	=VSTACK(C4,E3,F1) = {11 ; 10 ; 4}
9	=VSTACK(C1:D1,C2) = {1,2 ; 5,#N/A}
10	=VSTACK({"a","b"},C1:D1) = {"a","b" ; 1,2}
11	=VSTACK({"a" ; "b"},C1:D1) = {a,#N/A ; b,#N/A ; 1,2}

1 - What is the combination of the range "C1:D1" and "C2:D2" as one array.
2 - What is the combination of the range "C1:C2" and "D1:D2" as one array.
3 - What is the combination of the range "C1:D1" and "C3:D3" as one array.
4 - What is the combination of the range "C1:D1", "C2:D2" and "C3:D3" as one array.
5 - What is the combination of the range "C1:D1" and "C2:D3" as one array.
6 - What is the combination of the range "C1:C3" and "D1:D3" as one array.
7 - What is the combination of the range "C1:C4" and "D1:D4" as one array.
8 - What is the combination of the range "C4", "E3" and "F1" as one array. These individual values are placed in a vertical array.
9 - What is the combination of the range "C1:D1" and "C2" as one array. Notice the second array is a different size so #N/A is used as padding.
10 - What is the combination of the array {"a","b"} and "C1:D1" as one array. Notice the comma in the array. This is interpreted as a 1x2 (1 row, 2 column) array the same size as "C1:D1".
11 - What is the combination of the array {"a" ; "b"} and "C1:D1" as one array. Notice the semi-colon in the array. This is interpreted as a 2x2 (2 row, 2 column) array a different size to "C1:D1".