WORKDAY

WORKDAY(start_date, days [,holidays])

Returns the date serial number that is a given number of working days before or after a date.

start_date	The starting date.
days	The number of nonweekend and nonholiday days before or after "start_date".
holidays	(Optional) The dates to exclude from the working calendar, holidays and floating days.

REMARKS

* WORKDAY.INTL was added in Excel 2010 to replace this function.
* This function excludes weekends and any other dates specified in the "holidays" array.
* This function has an explicit assumption that weekends are Saturday and Sunday. The WORKDAY.INTL function allows you to specify what days you want to treat as weekends.
* If "start_date" is not a valid date, then #VALUE! is returned.
* If "start_date" plus "days" yields an invalid date, then #NUM! is returned.
* If "days" is not an integer, it is truncated.
* If "days" > 0, then a future date is returned.
* If "days" < 0, then an earlier date is returned.
* The "holidays" can be either a range of cells that contain the dates or an array constant of the serial numbers that represent the dates.
* If "holidays" is left blank, then only weekends will be excluded.
* If "holidays" has more than one date, you can either use an array constant or refer to a cell range.
* If "holidays" contains an invalid date, then #VALUE! is returned.
* You can use the DATE function to return the date as a date serial number given a year, month, day.
* You can use the DATEVALUE function to return the date serial number given a date in text format.
* You can use the DAYS function to return the number of days between two dates.
* You can use the DAYS360 function to return the number of days between two dates, based on 30 day months.
* You can use the NETWORKDAYS.INTL function to return the number of days excluding weekends and holidays.
* You can use the WEEKDAY function to return the day of the week for a given date.
* You can use the WORKDAY6 - User Defined Function function to assume a 6-day working week.
* You can use the WORKDAYSMISC - User Defined Function function to use other days as your workdays.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B	C	D
1	=WORKDAY("02/01/2010",0) = 40180	01/01/2010	40179	Friday
2	=WORKDAY("02/01/2010",1) = 40182	02/01/2010	40180	Saturday
3	=WORKDAY("02/01/2010",5) = 40186	03/01/2010	40181	Sunday
4	=WORKDAY("02/01/2010",6) = 40189	04/01/2010	40182	Monday
5	=WORKDAY("02/01/2010",2,"04/01/2010") = 40184	05/01/2010	40183	Tuesday
6	=WORKDAY("02/01/2000",2,"03/01/2000") = 36530	06/01/2010	40184	Wednesday
7	=WORKDAY("02/01/2000",2,B1:B3) = 36529	07/01/2010	40185	Thursday
8	=WORKDAY("02/01/2000",2,{"03/01/2000","04/01/2000"}) = 36531
9	=WORKDAY("01/01/1977",7,2) = 28136
10	=WORKDAY(1/1/1977,7,2) = 11
11	=WORKDAY(DATE(1977,1,1),7,2) = 28136
12	=WORKDAY(DATEVALUE("01/03/1998"),5) = 35860
13	=WORKDAY("01/02/2000",-10000000) = #NUM!
14	=WORKDAY("30/02/2000",2) = #VALUE!
15	=WORKDAY("02/01/2000",2,"30/02/2000") = #VALUE!

1 - What is the serial number for the date that is 0 days after 2-January-2010 (40180).
2 - What is the serial number for the date that is 1 day after 2-January-2010 (40180 + 2). Because the 2nd January is Saturday, 1 day would be Monday which is 2 days after.
3 - What is the serial number for the date that is 5 days after 2-January-2010 (40180 + 6). Because the 2nd January is Saturday. 5 days would be Friday which is 6 days after.
4 - What is the serial number for the date that is 6 days after 2-January-2010 (40180 + 9). Because the 2nd January is Saturday 6 days after be the following Monday which is 9 days after.
5 - What is the serial number for the date that is 2 days after 2-January-2010 (40180 + 4). Because the 2nd January is Saturday 2 days after would be Tuesday the 5-January but since the 4-January is considered to be a holiday it will actually be Wednesday which is 4 days after.