DMAX

DMAX(database, field, criteria)

Returns the largest value in a column that satisfies multiple conditions.

database	The range of cells that make up the table or list.
field	The column name or number indicating which column to use.
criteria	The range of cells that contain the conditions.

REMARKS

* For an illustrated example refer to the Specifying Database Criteria page.
* Any cells containing logical values, text and errors are not included. See Example 7.
* This function supports wildcards (? and *).
* The "database" range of cells can be a single column. See Example 5.
* The "database" range of cells must contain column headings in the first row.
* If the "database" range refers to a cell inside a pivot table, this will refer to the data currently displayed in the pivot table.
* The "field" can be a column label, a column number (left to right) or a cell reference.
* The "field" label is not case sensitive. See Example 2.
* If the "field" is left blank, then #VALUE! is returned.
* If the "field" column contains some text entries, then these are ignored.
* The "criteria" must include at least one column heading and one cell below the column heading.
* The "criteria" must be in a contiguous block of adjacent cells.
* If the "criteria" is on the same sheet, do not put it below the data, in case more data gets added.
* If the "criteria" is left blank, then #VALUE! is returned. See Example 18.
* Make sure the "criteria" and "database" ranges do not overlap and that they are always separated by at least one blank row or column.
* To perform an operation on an entire column, enter a blank cell below the column heading in the "criteria" range. See Example 10.
* If no rows match the criteria, then 0 is returned. See Example 15.
* You can use the MAX function to return the largest value with no conditions.
* You can use the MAXA function to return the largest value with no conditions (including logical values and text).
* You can use the MAXIFS function to return the largest value that satisfies multiple conditions.
* This is similar to DAVERAGE, DCOUNT, DGET, DMIN, DPRODUCT, DSTDEV, DSUM and DVAR functions.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B	C	D
1	=DMAX(B1:D10, "Qty", B12:B13) = 19	Date	Qty	Cost
2	=DMAX(B1:D10, "QTY", B12:B13) = 19	Jan	19	18,000
3	=DMAX(B1:D10, 2, B12:B13) = 19	Mar	20	24,000
4	=DMAX(B1:D10, "Cost", B12:B14) = 20,000	Feb	17	16,500
5	=DMAX(C1:C10, "Qty", C12:C13) = 21	Jun	22	20,000
6	=DMAX(B1:D10, "Qty", C12:C14) = 24		18	19,500
7	=DMAX(B1:D10, "Cost", C12:D13) = 24,000	Nov	21	24,000
8	=DMAX(B1:D10, "Qty", D12:D13) = 24	May	text	26,500
9	=DMAX(B1:D10, "Cost", B12:D14) = 20,000	Apr	17	18,500
10	=DMAX(B1:D10, "Cost", D16:D17) = 29,000	Mar	24	29,000
11	=DMAX(B1:D10, "Cost", C16:D17) = 29,000
12	=DMAX(B1:D10, "Cost", B19:B20) = 20,000	Date	Qty	Cost
13	=DMAX(B1:D10, "Date", C12:C13) = 0	Jan	<22	>20000
14	=DMAX(B1:D10, "Qty", B12:D13) = 0	Jun	>18
15	=DMAX(B1:D10, "text", B12:B13) = #VALUE!
16	=DMAX(B1:D10, "Qty", C12) = #VALUE!	Date	Qty	Cost
17	=DMAX(B1:D10, "Cost", C19) = #VALUE!	Jun	>18
18	=DMAX(B1:D10, "Qty", ) = #VALUE!
19	=DMAX(B2:D10, "Qty", B12:B13) = #VALUE!	Date
20	=DMAX(B1:D1, "Qty", B12:B14) = #VALUE!	J*

1 - What is the largest "Qty" when Date="Jan", using a field label.
2 - What is the largest "QTY" when Date="Jan", with the field label in uppercase.
3 - What is the largest "Qty" when Date="Jan", using a field number.
4 - What is the largest "Cost" when Date="Jan" or "Jun".
5 - What is the largest "Qty" when Qty<22. This uses a single column.
6 - What is the largest "Qty" when Qty<22 OR Qty>18.
7 - What is the largest "Cost" when Qty<22 AND Cost>20,000. The Cost for May is not included.
8 - What is the largest "Qty" when Cost>20,000.
9 - What is the largest "Cost" when Date="Jan", Qty<22, Cost>20,000 OR Date="Jun" and Qty>18.
10 - What is the largest "Cost" for all the items. Putting a blank cell below the column heading will refer to the entire column.
11 - What is the largest "Cost" when Qty>18 and Cost has no criteria.
12 - What is the largest "Cost" for all the dates that start with the letter "J".
13 - If the "field" column does not contain any numbers, then 0 is returned.
14 - If the "criteria" you specify does not return any rows, then 0 is returned. The Cost for January was only 18,000.
15 - If the "field" does not match one of the column headings, then #VALUE! is returned.
16 - If the "criteria" only includes a column heading, then #VALUE! is returned.
17 - If the "criteria" refers to a single empty cell, then #VALUE! is returned. C19 is empty.
18 - If the "criteria" is left blank, then #VALUE! is returned.
19 - If the "database" range does not include column headings, then #VALUE! is returned.
20 - If the "database" range only includes column headings, then #VALUE! is returned.