MEDIAN

MEDIAN(number1 [,number2] [..])

Returns the median value in a list or array of numbers.

number1	The first number.
number2	(Optional) The second number.

REMARKS

* The median is the middle of the distribution after the numbers have been sorted into ascending order.
* If there is an odd number of unique numbers in the set, then the number in the middle is returned. See Example 1.
* If there is an even number of unique numbers in the set, then the average of the two numbers in the middle is calculated. See Example 2.
* The arguments can be values, cell references, arrays or named ranges.
* If any arguments evaluate to zero, they are included.
* If any arguments evaluate to True or False, then they are ignored.
* If any arguments contain text, then #VALUE! is returned. Example 21.
* If any cell references contain text, then they are ignored. See Example 13.
* If any cell references are empty, then they are ignored.
* You can have a maximum of 255 arguments.
* You can use the AVERAGE function to return the arithmetic mean of a list of numbers.
* You can use the MODE.SNGL function to return the value that occurs most frequently.
* You can use the MEDIANIFS - User Defined Function to return the median value in a range of values that satisfies multiple conditions.
* You can use the MEDIANVISIBLE - User Defined Function to exclude hidden cells.
* You can use the MEDIANVISIBLEIFS - User Defined Function to exclude hidden cells.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B	C	D
1	=MEDIAN(1,2,3) = 2	4	3
2	=MEDIAN(1,2,3,4) = 2.5	2	1
3	=MEDIAN(4,3,2,1) = 2.5	5	6
4	=MEDIAN(B1,C1,B2,C2) = 2.5	500	40
5	=MEDIAN(1,2,3,4,5) = 3	30	600	text
6	=MEDIAN(2,10) = 6
7	=MEDIAN(1,4,5) = 4
8	=MEDIAN(1,4,6,5) = 4.5
9	=MEDIAN({1,4,6,5}) = 4.5
10	=MEDIAN(B1:B4) = 4.5
11	=MEDIAN(B1:B5) = $5.00
12	=MEDIAN(B5:C5) = $315.00
13	=MEDIAN(B5:D5) = $315.00
14	=MEDIAN(B1:C2) = 2.5
15	=MEDIAN(B1:D5) = 6
16	={MEDIAN(B1:C2)} = 2.5
17	={MEDIAN(B1:D5)} = 6
18	=MEDIAN(1,2,3,4,0) = 2
19	=MEDIAN({1,4,6,5,"some text"}) = 4.5
20	=MEDIAN({1,4,6,5,"some text",TRUE}) = 4.5
21	=MEDIAN(1,4,6,5,"some text",TRUE) = #VALUE!

9 - Using curly brackets to define an array of items is optional and is not related to pressing (Ctrl + Shift + Enter).
10 & 11 - Referencing a single vertical column will give the correct median value.
12 & 13 - Referencing a single horizontal row will also give the correct median value.
14 & 15 - Referencing more than a single row or column will also give the correct median value.
16 & 17 - Array Formulas. Referencing more than a single row or column will also give the correct median value. Entering these formulas using (Ctrl + Shift + Enter) is not necessary as the result is the same either way.
18 - Any zero values will be included. Compare this with 2.