Removing Blanks

There are a number of different array formulas that you can use to achieve this.
Each one has its own advantages and disadvantages.
Cells & Ranges > Removing Blank Cells Vertical

Manually

Highlight the cells containing the blank cells
Home Tab, Editing Group, Find & Select > GoTo Special
Select Blanks
This will select all the cells that are blank
Home Tab, Cells Group, Delete > Delete Cells, Entire Row

Example 1 - Vertical

=IF(ROWS(D$2:D2)>COUNTA(B:B),"",INDEX(B:B,SMALL(IF(B$2:B$12<>"",ROW(B$2:B$12)),ROWS(D$2:D2)))) 

assumes that there is nothing else in this column
can be dragged down
doesn't need to be on the same rows
only works on vertical lists

Example 2 - Vertical

=IF(COUNTIF($B$15:$B$25,"?*")<ROW(B15)-14,"",INDEX(B:B,SMALL(IF(B$15:B$25<>"",ROW(B$15:B$25)),ROWS(B$15:B15)))) 

can be used with other data in the column
can be dragged down
doesn't need to be on the same rows
only works on vertical lists

Example 3 - Vertical

=IF(ISERROR(SMALL(IF(B28:B38<>"",ROW(B28:B38)-27),ROW(B28:B38)-27)),"", 
INDEX(B28:B38,MATCH(SMALL(IF(B28:B38<>"",ROW(B28:B38)-27),ROW(B28:B38)-27),IF(B28:B38<>"",ROW(B28:B38)-27),0))) 

must be entered as one array formula block and cannot be dragged down
must enter the row number to subtract from the current ROW (in this example 7)
doesn't need to be on the same rows
only works on vertical lists

Example 4 - Vertical

Thank you to Chip Pearson (cpearson.com/excel/NoBlanks.aspx)

=IF(ROW()-ROW($B$41:$B$51)+1>ROWS($B$41:$B$51)-COUNTBLANK($B$41:$B$51),"", 
INDIRECT(ADDRESS(SMALL((IF($B$41:$B$51<>"",ROW($B$41:$B$51),ROW()+ROWS($B$41:$B$51))),ROW()- 
ROW($D$41:$D$51)+1),COLUMN($B$41:$B$51),4))) 

can be dragged down
doesn't have to be on the same rows
only works on vertical lists

Example 5 - Horizontal

=IF(COLUMN(B:B)<=SUM(--($B$2:$L$2<>""))+1,INDEX($B$2:$L$2,0,SMALL(IF($B$2:$L$2<>"",COLUMN($B$2:$L$2)-1,""),COLUMN(B:B)-1)),"") 

needs to be the in the same columns
can be dragged
only works on horizontal lists

Example 6

Use a VBA User Defined Function
NONBLANKVALUES - Returns a cell range with all the blanks removed.