LARGE

LARGE(array, k)

Returns the kth largest numerical value.

array	The array for which you want to determine the Kth largest value.
k	The position from the largest to return.

REMARKS

* This function can return multiple values.
* You can use this function to select a value based on its relative standing.
* An alternative way to find the Kth largest value is just to sort the data into descending order.
* Any text or non numerical values are ignored.
* Any duplicate numbers are counted the same as values that are different. See Example 4.
* If "array" is empty, then #NUM! is returned. See Example 18.
* If "k" <= 0, then #NUM! is returned. See Example 20.
* If "k" = 1, then the largest value is returned.
* If "k" = length of the "array", then the smallest value is returned.
* If "k" > length of the "array", then #NUM! is returned. Example 21.
* You can use the SMALL function to return the kth smallest value in a list or array of numbers.
* You can use the MAX function to return the largest value in a list of array of numbers.
* You can use the MIN function to return the smallest numerical value.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B
1	=LARGE({1, 2, 3}, 1) = 3	-5
2	=LARGE({6, 4, 5}, 2) = 5	-10
3	=LARGE({1, 5, 5, 5, 8}, 2) = 5	-15
4	=LARGE({1, 5, 5, 5, 8}, 4) = 5	1
5	=LARGE({-3, -2, 0, 3, 2}, 3) = 0	text
6	=LARGE({-3, -2, 0, 3, 2}, 5) = -3	True
7	=LARGE({1, 2, "3"}, 1) = 2	False
8	=LARGE(B1:B3, 1) = -5	=DATE(2024, 1, 1) = 01 Jan 2024
9	=LARGE(B4:B5, 1) = 1	=10/0 = #DIV/0!
10	=LARGE(B1:B3, B4) = -5
11	=LARGE({1, 2, 3, 4, 5, 6}, {1, 2}) = {6, 5}
12	=LARGE(B5:B7, 1) = #NUM!
13	=LARGE(B1:B9, 1) = #DIV/0!
14	=LARGE({1, 2, 3, 4, 5}, ) = #NUM!
15	=LARGE({1, 2, 3, 4, 5}, 10) = #NUM!

1 - What is the largest number in the values (1,2,3).
2 - What is the 2nd largest number in the values (4,5,6).
3 - What is the 2nd largest number in the values (1,5,5,5,8).
4 - What is the 4th largest number in the values (1,5,5,5,8).
5 - What is the 3rd largest number in the values (-3,-2,0,3,2).
6 - What is the 5th largest number in the values (-3,-2,0,3,2).
7 - What is the largest number in the values (1,2,"3").
8 - What is the largest number in the range "B1:B3".
9 - What is the largest number in the range "B4:B5".
10 - What is the largest number in the values (1,2,3).
11 - What are the top two largest numbers in the values (1,2,3,4,5,6).
12 - What is the largest number in the range "B5:B7".
13 - If any of the cells contain an error that error value is passed on.
14 - If "k" is left blank, then #NUM! is returned.
15 - If "k" > length of the "array", then #NUM! is returned.