MIN

MIN(number1 [,number2] [..])

Returns the smallest value in a list, range or array.

number1	The first number.
number2	(Optional) The second number.

REMARKS

* This function includes hidden cells.
* Arguments that are just numbers are included.
* Arguments that are just numbers passed as text ("3") are included. See Example 15.
* Arguments that are just logical values are included. True evaluates to 1. False evaluates to 0. See Example 19.
* Arguments that are just text will generate a #VALUE! error. See Example 16.
* Arguments that are references to empty cells are excluded. See Example 8.
* Arguments that are references to cells containing zeros are included. See Example 9.
* Arguments that are references to cells containing dates are included and the date serial number is used. See Example 12.
* Arguments that are references to cells containing logical values are excluded. See Example 11.
* Arguments that are references to cells containing text are excluded. See Example 10.
* Arguments that are arrays containing logical values are excluded.
* Arguments that are arrays containing text are excluded.
* If any cell references contain an error, then that error is returned.
* You can have a maximum of 255 arguments.
* You can use the AGGREGATE function to exclude hidden cells.
* You can use the MAX function to return the largest value in a list, range or array.
* You can use the MINA function to include logical values and text.
* You can use the MINIFS function to satisfy multiple conditions.
* You can use the MINBETWEEN - User Defined Function to return the smallest value that is between a range.
* You can use the MINVISIBLE - User Defined Function to exclude hidden cells.
* You can use the SMALL function to return the kth smallest value in a list or array of numbers.
* This is similar to the AVERAGE, COUNT and SUM functions.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B
1	=MIN(2,4) = 2	5
2	=MIN(5,10,15) = 5	10
3	=MIN(5,10,15,0) = 0	15
4	=MIN(-2,-3,4,5,6) = -3
5	=MIN({-2,-3,4,5,6}) = -3	0
6	=MIN(B1:B3) = 5	text
7	=MIN(B1,B2,B3) = 5	FALSE
8	=MIN(B1,B2,B3,B4) = 5	=DATE(2023,1,1) = 01 Jan 2023
9	=MIN(B1,B2,B3,B5) = 0	=10/0 = #DIV/0!
10	=MIN(B1,B2,B3,B6) = 5
11	=MIN(B1,B2,B3,B7) = 5
12	=MIN(B1,B2,B3,B8) = 5
13	=MIN(named_range) = 3
14	=MIN(B5,B6,B9) = #DIV/0!
15	=MIN(2,"3") = 2
16	=MIN(2,"some text") = #VALUE!
17	=MIN({2,"some text"}) = 2
18	=MIN(2,TRUE) = 1
19	=MIN(2,FALSE) = 0
20	=MIN({2,TRUE}) = 2

1 - What is the smallest of 2 and 4.
2 - What is the smallest of 5, 10 and 15.
3 - What is the smallest of 5, 10, 15 and 0.
4 - What is the smallest of -2, -3, 4, 5 and 6.
5 - What is the smallest of the values in the array (-2, -3, 4, 5, 6).
6 - What is the smallest of the values in range "B1:B3".
7 - What is the smallest of the values in range "B1", "B2" and "B3".
8 - What is the smallest of the values in range "B1", "B2", "B3" and "B4". B4 is empty.
9 - What is the smallest of the values in range "B1", "B2", "B3" and "B5".
10 - What is the smallest of the values in range "B1", "B2", "B3" and "B6".
11 - What is the smallest of the values in range "B1", "B2", "B3" and "B7".
12 - What is the smallest of the values in range "B1", "B2", "B3" and "B8". B8 is a date so this gets included as a date serial number.
13 - What is the smallest of the values in the named range that refers to the range "B1:B3".
14 - What is the smallest of the values in range "B5", "B6" and "B9". B9 contains an error so that gets returned.
15 - What is the smallest of 2 and 3. Text values that are actually numbers are included.
16 - What is the smallest of 2 and "some text". Text values passed as arguments are excluded.
17 - What is the smallest of the values in the array (2, "some text"). Text values inside arrays are excluded.
18 - What is the smallest of 2 and TRUE. Logical values passed as arguments are included.
19 - What is the smallest of 2 and FALSE. Logical values passed as arguments are excluded.
20 - What is the smallest of the values in the array (2, TRUE). Logical values inside arrays are excluded.