PRODUCT

PRODUCT(number1 [,number2] [..])

Returns the product of all the numerical values.

number1	The first number.
number2	(Optional) The second number.

REMARKS

* You can include logical arguments such as true or false. True =1, False=0.
* If an argument is an array or reference, only numbers in the array or reference are counted.
* If an argument is an array or reference, any empty cells, text, or error values are ignored.
* If any of the arguments are text, then #VALUE! is returned.
* You can have a maximum of 255 arguments.
* You can use the SUMPRODUCT function to return the sum of the product of one or more arrays of values.
* You can use the DPRODUCT function to return the product of the values in a column that satisfies multiple conditions.
* You can use the PRODUCTVISIBLE - User Defined Function to exclude hidden cells.
* This is similar to the AVERAGE, COUNT, MAX, MIN and SUM functions.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B
1	=PRODUCT(1, 2, 3) = 6	5
2	=PRODUCT(1, 2, 3, 0) = 0	10
3	=PRODUCT(-2, -3, 4, 5, 6) = 720	15
4	=PRODUCT({-2, -3, 4, 5, 6}) = 720
5	=PRODUCT(B1:B3) = 750	0
6	=PRODUCT(B1, B2, B3) = 750	text
7	=PRODUCT(B1, B2, B3, B4) = 750	True
8	=PRODUCT(B1, B2, B3, B5) = 0	False
9	=PRODUCT(B1, B2, B3, B6) = 750	=DATE(2024, 1, 1) = 01 Jan 2024
10	=PRODUCT(B1, B2, B3, B7) = 750	=10/0 = #DIV/0!
11	=PRODUCT(B1, B2, B3, B8) = 750
12	=PRODUCT(B1, B2, B3, B9) = 33969000
13	=PRODUCT(named_range) = 750
14	=PRODUCT(B1, B2, B3, B10) = #DIV/0!
15	=PRODUCT(2, "3") = 6
16	=PRODUCT(2, TRUE) = 2
17	=PRODUCT(2, FALSE) = 0
18	=PRODUCT(2, "some text") = #VALUE!
19	=PRODUCT({2, "some text"}) = 2
20	=PRODUCT({2, TRUE}) = 2

1 - What is the product of the values (1,2,3).
2 - What is the product of the values (1,2,3,0). Zeros are always included.
3 - What is the product of the values (-2,-3,4,5,6).
4 - What is the product of the values in the array {-2,-3,4,5,6}.
5 - What is the product of the values in range "B1:B3".
6 - What is the product of the values in range "B1", "B2" and "B3".
7 - What is the product of the values in range "B1", "B2", "B3" and "B4". B4 is empty. Empty cells are always excluded.
8 - What is the product of the values in range "B1", "B2", "B3" and "B5". B5 is zero so this gets included.
9 - What is the product of the values in range "B1", "B2", "B3" and "B6". B6 is text so this gets excluded.
10 - What is the product of the values in range "B1", "B2", "B3" and "B7". B7 is a logical value so this gets excluded.
11 - What is the product of the values in range "B1", "B2", "B3" and "B8". B8 is a logical value so this gets excluded.
12 - What is the product of the values in range "B1", "B2", "B3" and "B9". B9 is a date so this gets included as a date serial number.
13 - What is the product of the values in the named range that refers to the range "B1:B3".
14 - What is the product of the values in range "B1", "B2", "B3" and "B10". B10 contains an error so that gets returned.
15 - What is the product of these values (2, "3"). Text values that are actually numbers are included.
16 - What is the product of these values (2, TRUE). Logical values passed as arguments are included. TRUE is replaced with 1.
17 - What is the product of these values (2, FALSE). Logical values passed as arguments are included. FALSE is replaced with 0.
18 - What is the product of these values (2, "some text"). Text values passed as arguments are excluded.
19 - What is the product of the values in the array {2, "some text"}. Text values inside arrays are excluded.
20 - What is the product of the values in the array {2, TRUE}. Logical values inside arrays are excluded.