SUM

SUM(number1 [,number2] [..])

Returns the total of the numerical values.

number1	The first number.
number2	(Optional) The second number.

REMARKS

* For an illustrated example refer to the page under Advanced Functions
* This function includes hidden cells.
* Arguments that are just numbers are included.
* Arguments that are just numbers passed as text ("3") are included. See Example 15.
* Arguments that are just logical values are included. True evaluates to 1. False evaluates to 0. See Example 16.
* Arguments that are just text will generate a #VALUE! error. See Example 18.
* Arguments that are references to cells containing zeros are included. See Example 9.
* Arguments that are references to cells containing dates are included and the date serial number is used. See Example 12.
* Arguments that are references to cells containing logical values are excluded. See Example 11.
* Arguments that are references to cells containing text are excluded. See Example 10.
* Arguments that are references to cells containing error values will be returned. See Example 14.
* Arguments that are references to empty cells are excluded. See Example 8.
* Arguments that are arrays containing logical values are excluded. See Example 20.
* Arguments that are arrays containing text are excluded. See Example 19.
* You can have a maximum of 255 arguments.
* To sum all the values in column "C" use: "=SUM(C:C)". This function automatically finds the last used row in a column reference.
* There is also an AutoSum button to help you enter this function quickly.
* You can use the SUMIF function to return the total of the values that satisfies one condition.
* You can use the SUMIFS function to return the total of the values that satisfies multiple conditions.
* You can use the SUMPRODUCT function to return the sum of the product of one or more arrays of values.
* You can use the SUMSQ function to return the sum of the squares of all the values in a list, table or cell range.
* You can use the SUMFORMAT - User Defined Function to return the sum of all the values that have been formatted with multiple attributes.
* You can use the SUMVISIBLE - User Defined Function to exclude hidden cells.
* You can use the DSUM function to return the total of the values in a column that satisfies multiple conditions.
* You can use the AGGREGATE function to exclude hidden cells.
* This is similar to the AVERAGE, COUNT, MAX, MIN and PRODUCT functions.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B
1	=SUM(1, 2, 3) = 6	5
2	=SUM(1, 2, 3, 0) = 6	10
3	=SUM(-2, -3, 4, 5, 6) = 10	15
4	=SUM({-2, -3, 4, 5, 6}) = 10
5	=SUM(B1:B3) = 30	0
6	=SUM(B1, B2, B3) = 30	text
7	=SUM(B1, B2, B3, B4) = 30	True
8	=SUM(B1, B2, B3, B5) = 30	False
9	=SUM(B1, B2, B3, B6) = 30	=DATE(2024, 1, 1) = 01 Jan 2024
10	=SUM(B1, B2, B3, B7) = 30	=10/0 = #DIV/0!
11	=SUM(B1, B2, B3, B8) = 30
12	=SUM(B1, B2, B3, B9) = 45322
13	=SUM(named_range) = 30
14	=SUM(B1, B2, B3, B10) = #DIV/0!
15	=SUM(2, "3") = 5
16	=SUM(2, TRUE) = 3
17	=SUM(2, FALSE) = 2
18	=SUM(2, "some text") = #VALUE!
19	=SUM({2, "some text"}) = 2
20	=SUM({2, TRUE}) = 2

1 - What is the sum of the values (1,2,3).
2 - What is the sum of the values (1,2,3,0). Zeros are always included.
3 - What is the sum of the values (-2,-3,4,5,6).
4 - What is the sum of the values in the array {-2,-3,4,5,6}.
5 - What is the sum of the values in range "B1:B3".
6 - What is the sum of the values in range "B1", "B2" and "B3".
7 - What is the sum of the values in range "B1", "B2", "B3" and "B4". B4 is empty. Empty cells are always excluded.
8 - What is the sum of the values in range "B1", "B2", "B3" and "B5". B5 is zero so this gets included.
9 - What is the sum of the values in range "B1", "B2", "B3" and "B6". B6 is text so this gets excluded.
10 - What is the sum of the values in range "B1", "B2", "B3" and "B7". B7 is a logical value so this gets excluded.
11 - What is the sum of the values in range "B1", "B2", "B3" and "B8". B8 is a logical value so this gets excluded.
12 - What is the sum of the values in range "B1", "B2", "B3" and "B9". B9 is a date so this gets included as a date serial number.
13 - What is the sum of the values in the named range that refers to the range "B1:B3".
14 - What is the sum of the values in range "B1", "B2", "B3" and "B10". B10 contains an error so that gets returned.
15 - What is the sum of these values (2, "3"). Text values that are actually numbers are included.
16 - What is the sum of these values (2, TRUE). Logical values passed as arguments are included. TRUE is replaced with 1.
17 - What is the sum of these values (2, FALSE). Logical values passed as arguments are included. FALSE is replaced with 0.
18 - What is the sum of these values (2, "some text"). Text values passed as arguments are excluded.
19 - What is the sum of the values in the array {2, "some text"}. Text values inside arrays are excluded.
20 - What is the sum of the values in the array {2, TRUE}. Logical values inside arrays are excluded.