COUNT

COUNT(value1 [,value2] [..])

Returns the number of numerical values.

value1	The first value.
value2	(Optional) The second value.

REMARKS

* For an illustrated example refer to the page under Advanced Functions
* This function includes hidden cells.
* Arguments that are just numbers are included.
* Arguments that are just numbers passed as text ("3") are included. See Example 15.
* Arguments that are just logical values are included. True evaluates to 1. False evaluates to 0. See Example 16.
* Arguments that are just text are excluded. See Example 18.
* Arguments that are references to cells containing zeros are included. See Example 9.
* Arguments that are references to cells containing dates are included. See Example 12.
* Arguments that are references to cells containing logical values are excluded. See Example 11.
* Arguments that are references to cells containing text are excluded. See Example 10.
* Arguments that are references to cells containing error values are excluded. See Example 14.
* Arguments that are references to empty cells are excluded. See Example 8.
* Arguments that are arrays containing logical values are excluded. See Example 20.
* Arguments that are arrays containing text are excluded. See Example 19.
* You can have a maximum of 255 arguments.
* You can use the COUNTA function to include logical values, text and errors.
* You can use the COUNTBLANK function to return the number of blank cells.
* You can use the COUNTIF function to return the number of numerical values that satifies one condition.
* You can use the COUNTIFS function to return the number of numerical values that satisfies multiple conditions.
* You can use the COUNTBETWEEN - User Defined Function to return the number of cells that have a value that is between a range.
* You can use the COUNTFORMAT - User Defined Function to return the number of cells that have a particular cell color or font color.
* You can use the COUNTSUBSTRING - User Defined Function return the number of times a substring occurs in a larger text string.
* You can use the COUNTVISIBLE - User Defined Function to exclude hidden cells.
* You can use the DCOUNT function to return the number of numerical values in a column that satisfies multiple conditions.
* You can use the AGGREGATE function to exclude hidden cells.
* This is similar to the AVERAGE, MAX, MIN, PRODUCT and SUM functions.
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B
1	=COUNT(1, 2, 3) = 3	5
2	=COUNT(1, 2, 3, 0) = 4	10
3	=COUNT(-2, -3, 4, 5, 6) = 5	15
4	=COUNT({-2, -3, 4, 5, 6}) = 5
5	=COUNT(B1:B3) = 3	0
6	=COUNT(B1, B2, B3) = 3	text
7	=COUNT(B1, B2, B3, B4) = 3	TRUE
8	=COUNT(B1, B2, B3, B5) = 4	FALSE
9	=COUNT(B1, B2, B3, B6) = 3	=DATE(2024, 1, 1) = 01 Jan 2024
10	=COUNT(B1, B2, B3, B7) = 3	=10/0 = #DIV/0!
11	=COUNT(B1, B2, B3, B8) = 3
12	=COUNT(B1, B2, B3, B9) = 4
13	=COUNT(named_range) = 3
14	=COUNT(B1, B2, B3, B10) = 3
15	=COUNT(2, "3") = 2
16	=COUNT(2, TRUE) = 2
17	=COUNT(2, FALSE) = 2
18	=COUNT(2, "some text") = 1
19	=COUNT({2, "some text"}) = 1
20	=COUNT({2, TRUE}) = 1

1 - How many of these values are numerical (1,2,3).
2 - How many of these values are numerical (1,2,3,0). Zeros are always included.
3 - How many of these values are numerical (-2,-3,4,5,6).
4 - How many of the values are numerical in this array {-2,-3,4,5,6}.
5 - How many cells contain numerical values in the range "B1:B3".
6 - How many cells contain numerical values in the range "B1", "B2" and "B3".
7 - How many cells contain numerical values in the range "B1", "B2", "B3" and "B4". B4 is empty so this gets excluded.
8 - How many cells contain numerical values in the range "B1", "B2", "B3" and "B5". B5 is zero so this gets included.
9 - How many cells contain numerical values in the range "B1", "B2", "B3" and "B6". B6 is text so this gets excluded.
10 - How many cells contain numerical values in the range "B1", "B2", "B3" and "B7". B7 is a logical value so this gets excluded. TRUE is replaced with 1.
11 - How many cells contain numerical values in the range "B1", "B2", "B3" and "B7". B7 is a logical value so this gets excluded. FALSE is replaced with 0.
12 - How many cells contain numerical values in the range "B1", "B2", "B3" and "B8". B8 is a date so this gets included.
13 - How many cells contain numerical values in the named range that refers to the range "B1:B3".
14 - How many cells contain numerical values in the range "B1", "B2", "B3" and "B10". B10 contains an error so this gets excluded.
15 - How many of the values (2, "3") are numerical. Text values that are actually numbers are included.
16 - How many of the values (2, TRUE) are numerical. Logical values passed as arguments are included. TRUE is replaced with 1.
17 - How many of the values (2, FALSE) are numerical. Logical values passed as arguments are included. FALSE is replaced with 0.
18 - How many of the values (2, "some text") are numerical. Text values passed as arguments are excluded.
19 - How many of the values are numerical in the array {2, "some text"}. Text values inside arrays are excluded.
20 - How many of the values are numerical in the array {2, TRUE}. Logical values inside arrays are excluded.