MROUND

MROUND(number, multiple)

Returns the number rounded to the nearest multiple.

number	The number you want to round.
multiple	The nearest multiple you want the number rounded to.

REMARKS

* For an illustrated example refer to the Rounding Functions page.
* Numbers are rounded up (when last digit >=5) and rounded down (when last digit < 5).
* This function follows standard rounding rules.
* Numbers are rounded up when the remainder of number/multiple >= multiple/2.
* Numbers are rounded down when the remainder of number/multiple < multiple/2.
* If "number" is an exact multiple of "multiple", there is no rounding.
* If "number" is zero, then 0 is returned.
* If "multiple" = 10, the number will be rounded to a multiple of 10.
* If "multiple" is a decimal and "number" is a midpoint value, then you can get inconsistent results
* If "multiple" is a decimal and "number" might be a midpoint value, you should use =ROUND(number/multiple, 0) * multiple
* If "multiple" is zero, then 0 is returned.
* If "number" and "multiple" have different signs, then #NUM! is returned.
* To avoid any floating-point arithmetic it is best to adjust the parameters so they are integers and then divide the result.
* You can use the ROUND function to round to a certain number of decimal places or digits.
* You can use the ROUNDDOWN function to round towards zero to a certain number of decimal places or digits.
* You can use the ROUNDUP function to round away from zero to a certain number of decimal places or digits.
* You can use the CEILING.MATH function to return the number rounded up by default to a certain multiple.
* You can use the FLOOR.MATH function to return the number rounded down by default to a certain multiple.
* For the Microsoft documentation refer to support.microsoft.com

	A
1	=MROUND(0.9, 1) = 1
2	=MROUND(1.1, 1) = 1
3	=MROUND(1.5, 1) = 2
4	=MROUND(1.1, 3) = 0
5	=MROUND(1.5, 3) = 3
6	=MROUND(-13, -2) = -14
7	=MROUND(1234.567, 100) = 1200
8	=MROUND(15, 0) = 0
9	=MROUND(7.05, 0.1) = 7.10
10	=MROUND(6.05, 0.1) = 6.00
11	=MROUND(6.051, 0.1) = 6.10
12	=MROUND(NOW(), "0:20") = 12:40:00 PM
13	=MROUND(-13, 2) = #NUM!
14	=MROUND("text", 1) = #VALUE!
15	=ROUND(6.05/0.1, 0)*0.1 = 6.10
16	=MROUND(6.05*10, 1)/10 = 6.10

1 - What is 0.9 rounded to the nearest multiple of 1. Rounded up because (0.9/1.0) >= (1.0/2).
2 - What is 1.1 rounded to the nearest multiple of 1. Rounded down.
3 - What is 1.5 rounded to the nearest multiple of 1. Rounded up.
4 - What is 1.1 rounded to the nearest multiple of 3. Rounded down.
5 - What is 1.5 rounded to the nearest multiple of 3. Rounded up.
6 - What is -13 rounded to the nearest multiple of -2. Rounded down.
7 - What is 1234.567 rounded to the nearest multiple of 100. Rounded down.
8 - What is 15 rounded to the nearest multiple of 0. The only multiple of 0 is zero.
9 - What is 7.05 rounded to the nearest multiple of 0.1. Rounded up to to 7.1.
10 - What is 6.05 rounded to the nearest multiple 0.1. Rounded down to 6.0. This is inconsistent.
11 - What is 6.051 rounded to the nearest multiple of 0.1. Rounded up to 6.1.
12 - What is the current time rounded to the nearest 20 minutes.
13 - The numbers have different signs.
14 - Both the numbers are not numeric.
15 - What is 6.05 rounded to the nearest multiple of 0.1. Using an equivalent formula.
16 - What is 6.05 rounded to the nearest multiple of 0.1. Using integer arguments and then dividing the result.