OR

OR(logical1 [,logical2] [..])

Returns the logical OR for any number of arguments.

logical1The first logical value or condition.
logical2(Optional) The second logical value or condition.

REMARKS
* This function returns either True or False.
* This function will only return single (aggregated) values so it cannot be used to return multiple values.
* This function is not case sensitive when matching text strings.
* This function does not support wildcards (? and *).
* This function does not use short circuiting evaluation.
* This function will return True if any of the logical arguments are True.
* This function will return False if all the logical arguments are False.
* The logical values can be constants, logical equations, cell references or named ranges.
* Any numbers (except 0) are True.
* Any empty cells are ignored.
* If any argument does not evaluate to either True or False, then #VALUE! is returned.
* This function can be used to check if values meet certain criteria.
* You can have a maximum of 255 arguments.
* You can use the AND function to return the logical AND for any number of arguments.
* You can use the NOT function to return the opposite of a True or False value.
* You can use the XOR function to return the logical exclusive OR for any number of arguments.
* The equivalent VBA operator is VBA.OR
* For the Microsoft documentation refer to support.microsoft.com

 AB
1=OR(FALSE,FALSE) = False5
2=OR(TRUE,FALSE) = True10
3=OR(FALSE,TRUE) = Truesome text
4=OR(1,1) = True 
5=OR(0,0) = False 
6=OR({FALSE},{FALSE}) = False 
7=OR({TRUE,FALSE}) = True 
8=OR(1+1=1,2+2=5) = False 
9=OR(2*3=6,5/2=2) = True 
10=OR(B1<=B2,20>=B2) = True 
11=OR(B3,TRUE) = True 
12=OR(TRUE,"some text") = True 
13=OR("SOME TEXT"="some text") = True 
14=OR(B1:B3=10) = True 
15=IF(OR(B1>0,B2<20),"yes","no") = yes 
16=OR("some text") = #VALUE! 

1 - What is the logical OR for False and False.
2 - What is the logical OR for True and False.
3 - What is the logical OR for False and True.
4 - What is the logical OR for the values 1 and 1.
5 - What is the logical OR for the values 0 and 0.
6 - What is the logical OR for two arrays containing the values False and False.
7 - What is the logical OR for one array containing the values True and False.
8 - What is the logical OR for the expression (1+1=2) and (2+2=5).
9 - What is the logical OR for the expression (2*3=6) and (5/2=2).
10 - What is the logical OR for the formulas (B1<=B2) and (20>=B2).
11 - What is the logical OR for the cell reference B3 and True.
12 - What is the logical OR for True and a text string.
13 - What is the logical OR when comparing two text strings. This function is not case sensitive.
14 - Do any of the cells in the range "B1:B3" contain the value 10.
15 - This function is often combined with the IF function.
16 - This function returns #VALUE! if any arguments do not evaluate to True or False.

© 2022 Better Solutions Limited. All Rights Reserved. © 2022 Better Solutions Limited Top