AND

AND(logical1 [,logical2] [..])

Returns the logical AND for any number of arguments.

logical1	The first logical value or condition.
logical2	(Optional) The second logical value or condition.

REMARKS

* This function returns either True or False.
* This function will only return single (aggregated) values so it cannot be used to return multiple values.
* This function is not case sensitive when matching text strings.
* This function does not support wildcards (? and *).
* This function does not use short circuiting evaluation.
* This function will return True if all the logical arguments are True.
* This function will return False if all the logical arguments are False.
* The logical values can be constants, logical equations, cell references or named ranges.
* Any numbers (except 0) are True.
* Any empty cells are ignored.
* If any argument does not evaluate to either True or False, then #VALUE! is returned.
* This function can be used to check if values meet certain criteria.
* You can have a maximum of 255 arguments.
* You can use the IF function to return a value based on whether a condition is True or False.
* You can use the OR function to return the logical OR for any number of arguments.
* You can use the NOT function to return the opposite of a True or False value.
* You can use the XOR function to return the logical exclusive OR for any number of arguments.
* The equivalent VBA operator is VBA.AND
* For the Microsoft documentation refer to support.microsoft.com
* For the Google documentation refer to support.google.com

	A	B
1	=AND(TRUE,TRUE) = True	5
2	=AND(TRUE,FALSE) = False	10
3	=AND(FALSE,TRUE) = False	some text
4	=AND(1,1) = True
5	=AND(0,0) = False
6	=AND({TRUE},{FALSE}) = False
7	=AND({FALSE,FALSE}) = False
8	=AND(5<10,20>10) = True
9	=AND(10<5,10>20) = False
10	=AND(B1<=B2,20>=B2) = True
11	=AND(B3,TRUE) = True
12	=AND(TRUE,"some text") = True
13	=AND("SOME TEXT"="some text") = True
14	=IF(AND(B1>0,B2<20),"yes","no") = yes
15	=AND("SOME TEXT") = #VALUE!

1 - What is the logical AND for True and True.
2 - What is the logical AND for True and False.
3 - What is the logical AND for False and True.
4 - What is the logical AND for the values 1 and 1.
5 - What is the logical AND for the values 0 and 0.
6 - What is the logical AND for two arrays containing the values False and False.
7 - What is the logical AND for one array containing the values False and False.
8 - What is the logical AND for (5<10) and (20>10).
9 - What is the logical AND for (10<5) and (10>20).
10 - What is the logical AND for the formulas (B1<=B2) and (20>=B2).
11 - What is the logical AND for the cell reference B3 and True.
12 - What is the logical AND for True and a text string.
13 - What is the logical AND for comparing two text strings. This function is not case sensitive.
14 - This function is often combined with the IF function.
15 - This function returns #VALUE! if any arguments do not evaluate to True or False.